
EdgeDB client for Elixir
    

edgedb-elixir is the EdgeDB client for Elixir. The documentation for client
  is available on edgedb.com and on
  hex.pm.

  
    
  
  Installation


edgedb-elixir is available on hex.pm and can be installed via mix.
  Just add :edgedb to your dependencies in the mix.exs file:
{:edgedb, "~> 0.1"}

  
    
  
  JSON support


EdgeDB comes with JSON support out of the box via the Jason library.
  To use it, add :jason to your dependencies in the mix.exs file:
{:jason, "~> 1.0"}
The JSON library can be configured using the :json option in the :edgedb application configuration:
config :edgedb,
    json: CustomJSONLibrary
The JSON library is injected in the compiled EdgeDB code, so be sure to recompile EdgeDB if you change it:
$ mix deps.clean edgedb --build


  
    
  
  Timex support


EdgeDB can work with Timex out of the box. If you define Timex as an application dependency,
  EdgeDB will use Timex.Duration to encode and decode the std::duration type from database.
  If you don't like this behavior, you can set EdgeDB to ignore Timex using
  the :timex_duration option by setting this to false in the :edgedb application configuration:
config :edgedb,
    timex_duration: false
EdgeDB will inject the use of Timex into the std::duration codec at compile time,
  so be sure to recompile EdgeDB if you change this behavior:
$ mix deps.clean edgedb --build


  
    
  
  License


This project is licensed under the terms of the Apache 2.0 license.
  See LICENSE for details.


  

    
Usage
    

The basic user API for edgedb-elixir is provided by the EdgeDB module and in most cases you will use only it.
  The exception is when you want to define custom codecs. Checkout the guide on
  hex.pm or on
  edgedb.com for more information.
EdgeDB provides several functions for querying data from the database, which are named in EdgeDB.query*/4 format.
  Transactions are supported with EdgeDB.transaction/3 function.

  
    
  
  Establishing a connection


edgedb-elixir, like other EdgeDB clients, allows a very flexible way to define how to connect to an instance.
  For more information, see EdgeDB.connect_option/0.
The examples on this page will involve connecting to an instance using
  edgedb projects.
  Run edgedb project init to initialize the project:
$ edgedb project init


  
    
  
  Database schema


Ensure that your database has the following schema:
module default {
    type User {
        required name: str {
            constraint exclusive;
        };
    }

    type Post {
        required body: str;

        required author: User;
        multi comments: Post;
    }
};
Let's fill the database with some data, which will be used in further examples:
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> EdgeDB.query!(client, """
...(2)> WITH
...(2)>     p1 := (
...(2)>         insert Post {
...(2)>             body := 'Yes!',
...(2)>             author := (
...(2)>                 insert User {
...(2)>                     name := 'commentator1'
...(2)>                 }
...(2)>             )
...(2)>         }
...(2)>     ),
...(2)>     p2 := (
...(2)>         insert Post {
...(2)>             body := 'Absolutely amazing',
...(2)>             author := (
...(2)>                 insert User {
...(2)>                     name := 'commentator2'
...(2)>                 }
...(2)>             )
...(2)>         }
...(2)>     ),
...(2)>     p3 := (
...(2)>         insert Post {
...(2)>             body := 'FYI here is a link to the Elixir client: https://hex.pm/packages/edgedb',
...(2)>             author := (
...(2)>                 insert User {
...(2)>                     name := 'commentator3'
...(2)>                 }
...(2)>             )
...(2)>         }
...(2)>     )
...(2)> insert Post {
...(2)>     body := 'EdgeDB is awesome! Try the Elixir client for it',
...(2)>     author := (
...(2)>         insert User {
...(2)>             name := 'author1'
...(2)>         }
...(2)>     ),
...(2)>     comments := {p1, p2, p3}
...(2)> }
...(2)> """)

  
    
  
  Querying data from EdgeDB


Depending on the expected results of the query, you can use different functions to retrieve data from the database.
  This is called the cardinality of the result and is better explained in
  the relevant documentation.

  
    
  
  Querying a set of elements


If you want to receive an EdgeDB.Set from your query, just use the EdgeDB.query/4 or EdgeDB.query!/4 functions.
  The difference between the two functions is that EdgeDB.query/4 will return an :ok tuple with result
  if successful or a :error  tuple with EdgeDB.Error if an error occurred during the query execution.
  EdgeDB.query!/4 will return a plain result if successful or raise EdgeDB.Error if error.
Let's query all existing posts with their bodies:
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> {:ok, posts} = EdgeDB.query(client, "select Post { body }")
{:ok,
 #EdgeDB.Set<{#EdgeDB.Object<body := "EdgeDB is awesome! Try the Elixir client for it">,
  #EdgeDB.Object<body := "Yes!">, #EdgeDB.Object<body := "Absolutely amazing">,
  #EdgeDB.Object<body := "FYI here is a link to the Elixir client: https://hex.pm/packages/edgedb">}>}
We can iterate over EdgeDB.Set and inspect each object separately:
iex(3)> Enum.each(posts, fn post ->
...(3)>   IO.inspect(post[:body], label: "post (#{inspect(post.id)})")
...(3)> end)
post ("3c5c8cf2-860f-11ec-a22a-2b0ab4e21d4b"): "EdgeDB is awesome! Try the Elixir client for it"
post ("3c5c904e-860f-11ec-a22a-f7cdb9bcb510"): "Yes!"
post ("3c5c9256-860f-11ec-a22a-0343fa0961f3"): "Absolutely amazing"
post ("3c5c9378-860f-11ec-a22a-0713dfca8baa"): "FYI here is a link to the Elixir client: https://hex.pm/packages/edgedb"
:ok

  
    
  
  Querying a single element


If you know that the query will return only one element or none, you can use EdgeDB.query_single/4 and
  EdgeDB.query_single!/4 functions. This function will automatically unpack the underlying EdgeDB.Set
  and return the requested item (or nil if the set is empty).
Let's query a post with a link to the Elixir client for EdgeDB:
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> post = EdgeDB.query_single!(client, "select Post filter contains(.body, 'https://hex.pm/packages/edgedb') limit 1")
iex(3)> post[:id]
"3c5c9378-860f-11ec-a22a-0713dfca8baa"
If we try to select a Post that does not exist, nil will be returned:
iex(4)> EdgeDB.query_single!(client, "select Post filter .body = 'lol' limit 1")
nil

  
    
  
  Querying a required single element


In case we want to ensure that the requested element must exist, we can use the functions EdgeDB.query_required_single/4 and
  EdgeDB.query_required_single!/4. Instead of returning nil they will return EdgeDB.Error in case of a missing element:
iex(5)> EdgeDB.query_required_single!(client, "select Post filter .body = 'lol' limit 1")
** (EdgeDB.Error) NoDataError: expected result, but query did not return any data

  
    
  
  Transactions


NOTE
Note that EdgeDB.transaction/3 calls can not be nested.
The API for transactions is provided by the EdgeDB.transaction/3 function:
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> {:ok, user} =
...(2)>  EdgeDB.transaction(client, fn conn ->
...(2)>    EdgeDB.query_required_single!(conn, "insert User { name := <str>$username }", username: "user1")
...(2)>  end)
Transactions can be rollbacked using the EdgeDB.rollback/2 function or automatically
  if an error has occurred inside a transaction block:
iex(3)> {:error, :rollback} =
...(3)>  EdgeDB.transaction(client, fn conn ->
...(3)>    EdgeDB.query_required_single!(conn, "insert User { name := <str>$username }", username: "wrong_username")
...(3)>    EdgeDB.rollback(conn)
...(3)>  end)
iex(4)> EdgeDB.query_single!(client, "select User { name } filter .name = <str>$username", username: "wrong_username")
nil
Transactions are retriable. This means that if certain types of errors occur when querying data from the database,
  the transaction block can be automatically retried.
The following types of errors can be retried retried:
	TransactionConflictError and its inheritors.
	Network errors (e.g. a socket was closed).

As an example, let's create a transaction conflict to show how this works. In the first example, we will disable retries:
iex(5)> callback = fn conn, body ->
...(5)>  Process.sleep(500)
...(5)>  EdgeDB.query!(conn, "update Post filter .author.id = <uuid>$user_id set { body := <str>$new_body }", user_id: user.id, new_body: body)
...(5)>  Process.sleep(500)
...(5)> end
iex(6)> spawn(fn ->
...(6)>  {:ok, client} = EdgeDB.start_link()
...(6)>  EdgeDB.transaction(client, &callback.(&1, "new_body_1"))
...(6)> end)
iex(7)> EdgeDB.transaction(client, &callback.(&1, "new_body_2"), retry: [transaction_conflict: [attempts: 0]])
** (EdgeDB.Error) TransactionSerializationError: could not serialize access due to concurrent update
Now let's execute the same thing but with enabled retries:
iex(8)> spawn(fn ->
...(8)>  {:ok, client} = EdgeDB.start_link()
...(8)>  EdgeDB.transaction(client, &callback.(&1, "new_body_1"))
...(8)> end)
iex(9)> EdgeDB.transaction(client, &callback.(&1, "new_body_2"))
{:ok, :ok}
All failed transactions will be retried until they succeed or until the number of retries exceeds the limit (the default is 3).

  
    
  
  Example


You can also check out an example application using this client to see how to work with it:
https://github.com/nsidnev/edgebeats


  

    
Datatypes
    

EdgeDB client for Elixir automatically converts EdgeDB types to the corresponding Elixir types and vice versa.
The table below shows the correspondence between EdgeDB and Elixir types.
	EdgeDB	Elixir	Example
	std::str	String.t/0	"Hello EdgeDB!"
	std::int16, std::int32, std::int64	integer/0	16
	std::float32, std::float64	float/0	3.1415
	std::bigint, std::decimal	Decimal.t/0	#Decimal<1.23>
	std::bool	boolean/0	true, false
	std::datetime	DateTime.t/0	~U[2018-05-07 15:01:22Z]
	std::duration	integer/0 or Timex.Duration	-420000000, #<Duration(PT7M)>
	cal::local_datetime	NaiveDateTime.t/0	~N[2018-05-07 15:01:22]
	cal::local_date	Date.t/0	~D[2018-05-07]
	cal::local_time	Time.t/0	~T[15:01:22]
	cal::relative_duration	EdgeDB.RelativeDuration.t/0	#EdgeDB.RelativeDuration<"PT45.6S">
	cal::date_duration	EdgeDB.DateDuration.t/0	#EdgeDB.DateDuration<"P4Y12D">
	std::json	any/0	42
	std::uuid	String.t/0	"0eba1636-846e-11ec-845e-276b0105b857"
	std::bytes	binary/0	<<1, 2, 3>>, "some bytes"
	cfg::memory	EdgeDB.ConfigMemory.t/0	#EdgeDB.ConfigMemory<"5KiB">
	ext::pgvector::vector	list/0	[1.5, 2.0, 4.5]
	anyenum	String.t/0	"green"
	array<anytype>	list/0	[1, 2, 3]
	anytuple	tuple/0 or EdgeDB.NamedTuple.t/0	{1, 2, 3}, #EdgeDB.NamedTuple<a: 1, b: 2, c: 3>}
	range	EdgeDB.Range.t/0	#EdgeDB.Range<[1.1, 3.3)>
	object	EdgeDB.Object.t/0	#EdgeDB.Object<name := "username">}
	set	EdgeDB.Set.t/0	#EdgeDB.Set<{1, 2, 3}>}



  

    
Custom codecs for EdgeDB scalars
    

EdgeDB.Protocol.Codec is a codec that knows how to encode or decode Elixir types into EdgeDB types
  and vice versa using the EdgeDB binary format.
Custom codecs can be useful when your EdgeDB scalars need their own processing.
NOTE
Although most of the client API is complete, some internal parts may be changed in the future.
  The implementation of the binary protocol (including the definition of custom codecs) is on the list of possible changes.
In most cases you can use already defined codecs to work with the EdgeDB binary protocol. Otherwise,
  you will need to check to the EdgeDB binary protocol documentation.
To implement custom codec it will be required to implement EdgeDB.Protocol.CustomCodec behaviour
  and implement EdgeDB.Protocol.Codec protocol.
As an example, let's create a custom codec for a scalar that extends the standard std::json type.
module default {
    scalar type JSONPayload extending json;

    type User {
        required name: str {
            constraint exclusive;
        };

        required payload: JSONPayload;
    }
};
We will convert the following structure to default::JSONPayload:
defmodule MyApp.Users.Payload do
  defstruct [
    :public_id,
    :first_name,
    :last_name
  ]

  @type t() :: %__MODULE__{
          public_id: integer(),
          first_name: String.t(),
          last_name: String.t()
        }
end
The implementation of the codec itself:
defmodule MyApp.EdgeDB.Codecs.JSONPayload do
  @behviour EdgeDB.Protocol.CustomCodec

  defstruct []

  @impl EdgeDB.Protocol.CustomCodec
  def new do
    %__MODULE__{}
  end

  @impl EdgeDB.Protocol.CustomCodec
  def name do
    "default::JSONPayload"
  end
end

defimpl EdgeDB.Protocol.Codec, for: MyApp.EdgeDB.Codecs.JSONPayload do
  alias EdgeDB.Protocol.{
    Codec,
    CodecStorage
  }

  alias MyApp.EdgeDB.Codecs.JSONPayload
  alias MyApp.Users.Payload

  @impl Codec
  def encode(_codec, %Payload{} = payload, codec_storage) do
    json_codec = CodecStorage.get_by_name(codec_storage, "std::json")
    Codec.encode(json_codec, Map.from_struct(payload), codec_storage)
  end

  @impl Codec
  def encode(_codec, value, codec_storage) do
    raise EdgeDB.InterfaceError.new(
            "unexpected value to encode as #{inspect(JSONPayload.name())}: #{inspect(value)}"
          )
  end

  @impl Codec
  def decode(_codec, data, codec_storage) do
    json_codec = CodecStorage.get_by_name(codec_storage, "std::json")
    payload = Codec.decode(json_codec, data, codec_storage)
    %Payload{
      public_id: payload["public_id"]
      first_name: payload["first_name"]
      last_name: payload["last_name"]
    }
  end
end
Now let's test this codec:
iex(1)> {:ok, client} = EdgeDB.start_link(codecs: [MyApp.EdgeDB.Codecs.JSONPayload])
iex(2)> payload = %MyApp.Users.Payload{public_id: 1, first_name: "Harry", last_name: "Potter"}
iex(3)> EdgeDB.query!(client, "insert User { name := <str>$username, payload := <JSONPayload>$payload }", username: "user", payload: payload)
iex(4)> object = EdgeDB.query_required_single!(client, "select User {name, payload} filter .name = 'user' limit 1")
#EdgeDB.Object<name := "user", payload := %MyApp.Users.Payload{
  first_name: "Harry",
  last_name: "Potter",
  public_id: 1
}>


  

    
Changelog
    

All notable changes to this project will be documented in this file.
The format is based on Keep a Changelog,
and this project adheres to Semantic Versioning.

  
    
  
  [0.8.0] - 2025-02-26


Compare with 0.7.0
NOTE
This is the last release of this client under the name edgedb
as the product name changes to gel.
The next release of this client (0.9.0) will not add any new functionality,
but will rename all modules and references from EdgeDB to Gel.

  
    
  
  Added


	support for Gel connection options.
	support for Elixir v1.17.
	support for Elixir v1.18.


  
    
  
  [0.7.0] - 2024-05-05


Compare with 0.6.1

  
    
  
  Added


	rendering hints for query errors from EdgeDB.
	support for EdgeDB binary protocol 2.0.
	new EdgeDB.MultiRange type to represent multiranges from EdgeDB 4.0.
	EdgeDB.Object.id/1 to fetch ID from an EdgeDB.Object if it was returned from the query.
	EdgeDB.ConfigMemory.new/1 to create a new instance of EdgeDB.ConfigMemory.t/0.
	support for Elixir v1.16.
	support for branches.
	support for server name (SNI) passing to TLS connection.


  
    
  
  Changed


	EdgeDB.Object.t/0 to be opaque.
	the behavior of injecting an implicit :id field into objects so that this no longer happens.


  
    
  
  Fixed


	client state handling in EdgeDB.with_config/2/EdgeDB.without_config/2,
  EdgeDB.with_globals/2/EdgeDB.without_globals/2 and
  EdgeDB.with_module_aliases/2/EdgeDB.without_module_aliases/2.


  
    
  
  [0.6.1] - 2023-07-07


Compare with 0.6.0

  
    
  
  Added


	support for Elixir v1.15 and Erlang/OTP 26.


  
    
  
  Fixed


	encoding of EdgeDB.Range.t/0 values.
	constructing EdgeDB.Range.t/0 from EdgeDB.Range.new/3 with nil as values.
	examples in the documentation and the Inspect implementation of
  EdgeDB.DateDuration.t/0 and EdgeDB.Range.t/0.


  
    
  
  [0.6.0] - 2023-06-22


Compare with 0.5.1

  
    
  
  Added


	support for cal::date_duration EdgeDB type via EdgeDB.DateDuration structure.
	support for EdgeDB Cloud.
	support for tuples and named tuples as query arguments.
	support for EdgeDB 3.0.
	support for ext::pgvector::vector type.


  
    
  
  Changed


	implementation of Enumerable protocol for EdgeDB.Set.
	EdgeDB.State to EdgeDB.Client.State, EdgeDB.with_state/2 to
  EdgeDB.with_client_state/2, :state option to :client_state.
	license from MIT to Apache 2.0.


  
    
  
  Fixed


	crash after updating db_connection to 2.5.
	decoding a single propery for EdgeDB.Object that equals to an empty set.
	not catching an EdgeDB.Error exception during parameters encoding,
  which caused throwing an exception for non-! functions.
	silent error for calling EdgeDB API with wrong module names.


  
    
  
  Removed


	EdgeDB.subtransaction/2, EdgeDB.subtransaction!/2 functions and other mentions of
  subtransactions support in the client.
	support for custom pool configuration.
	:raw option from EdgeDB.query* functions as well as access to EdgeDB.Query
  and EdgeDB.Result.
	API for constructing an EdgeDB.Error.


  
    
  
  [0.5.1] - 2022-08-25


Compare with 0.5.0

  
    
  
  Removed


	unintentional ping log for the connection.


  
    
  
  [0.5.0] - 2022-08-20


Compare with 0.4.0

  
    
  
  Added


	EdgeDB.Client module that is acceptable by all EdgeDB API.
	:max_concurrency option to start pool to control max connections count in EdgeDB.Pool.


  
    
  
  Changed


	default pool from DBConnection.Pool to EdgeDB.Pool.
	EdgeDB.Pool to be "real" lazy and dynamic: all idle connections that EdgeDB wants to drop
  will be disconnected from the pool, new connections will be created only on user queries
  depending on EdgeDB concurrency suggest as soft limit and :max_concurrency option as hard limit
  of connections count.
	first parameter accepted by callbacks in EdgeDB.transaction/3, EdgeDB.subtransaction/2
  and EdgeDB.subtransaction!/2 from DBConnection.t/0 to EdgeDB.Client.t/0.
	EdgeDB.connection/0 to EdgeDB.client/0.
	EdgeDB.edgedb_transaction_option/0 to EdgeDB.Client.transaction_option/0.
	EdgeDB.retry_option/0 to EdgeDB.Client.retry_option/0.
	EdgeDB.retry_rule/0 to EdgeDB.Client.retry_rule/0.


  
    
  
  Fixed


	concurrent transactions when client was unintentionally marked as borrowed for transaction instead of connection.


  
    
  
  Removed


	EdgeDB.WrappedConnection module in favor of EdgeDB.Client.


  
    
  
  [0.4.0] - 2022-08-04


Compare with 0.3.0

  
    
  
  Added


	support for EdgeDB 2.0 with new binary protocol.
	support for EdgeQL state via EdgeDB.State.
	new EdgeDB.Range type to represent ranges from EdgeDB 2.0.
	support for multiple EdgeQL statements execution via EdgeDB.execute/4 and EdgeDB.execute!/4.


  
    
  
  Changed


	io_format option to output_format.


  
    
  
  Fixed


	the ability to pass maps or keyword lists in a query that requires positional arguments.


  
    
  
  [0.3.0] - 2022-05-29


Compare with 0.2.1

  
    
  
  Added


	maps as a valid type for query arguments.
	EdgeDB.Object.to_map/1 and EdgeDB.NamedTuple.to_map/1 functions.
	optional support for std::datetime EdgeDB type via Timex.Duration structure.
	custom modules for each EdgeDB exception with the new/2 function, that will return the EdgeDB.Error exception.
	documentation for EdgeDB.Error functions that create new exceptions.


  
    
  
  Removed


	legacy arguments encoding.


  
    
  
  Changed


	EdgeQL queries to be lowercase.
	EdgeDB.Error.inheritor?/2 to work with generated module names for EdgeDB exceptions instead of atoms.


  
    
  
  [0.2.1] - 2022-05-19


Compare with 0.2.0

  
    
  
  Removed


	mention of :repeatable_read option for transaction isolation mode from t:EdgeDB.edgedb_transaction_option/0.


  
    
  
  Fixed


	codec name returned by codec for std::str from std::uuid to str::str.
	documentation for the custom codec example, which did not have a EdgeDB.Protocol.Codec.decode/3 implementation and used the wrong protocol.


  
    
  
  [0.2.0] - 2022-05-03


Compare with 0.1.0

  
    
  
  Added


	EdgeDB.Object.fields/2, EdgeDB.Object.properties/2, EdgeDB.Object.links/1 and EdgeDB.Object.link_properties/1 functions to inspect the fields of the object.
	EdgeDB.Error.inheritor?/2 function to check if the exception is an inheritor of another EdgeDB error.
	EdgeDB.Sandbox module for use in tests involving database modifications.
	EdgeDB.Pool to support dynamic resizing of the connection pool via messages from EdgeDB server.


  
    
  
  Fixed


	creation of EdgeDB.Object properties equal to an empty EdgeDB.Set.
	access to TLS certificate from connection options.
	isolation configuration by dropping REPEATABLE READ mode, because only SERIALIZABLE is supported by EdgeDB 1.0 (REPEATABLE READ was dropped in EdgeDB 1.3).
	preserving the order of the values returned when working with EdgeDB.NamedTuple (EdgeDB.NamedTuple.to_tuple/1, EdgeDB.NamedTuple.keys/1), including Enumerable protocol implementation.


  
    
  
  Changed


	parsing of binary data from EdgeDB by completely reworking the protocol implementation.
	internal implementation of the Access behaviour for EdgeDB.Object to improve fields access performance.


  
    
  
  [0.1.0] - 2022-02-10


Compare with first commit

  
    
  
  Added


	First release.



  

    
EdgeDB 
    



      
EdgeDB client for Elixir.
EdgeDB module provides an API to run a connection pool, query EdgeDB, perform transactions
  and their rollback.
A simple example of how to use it:
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> EdgeDB.query!(client, """
...(2)>   select v1::Person{
...(2)>     first_name,
...(2)>     middle_name,
...(2)>     last_name
...(2)>   } filter .last_name = <str>$last_name;
...(2)> """, last_name: "Radcliffe")
#EdgeDB.Set<{#EdgeDB.Object<first_name := "Daniel", middle_name := "Jacob", last_name := "Radcliffe">}>

EdgeDB.Client 
    



      
Сlient is a structure that stores a custom configuration to execute EdgeQL queries
  and has a reference to a connection or pool of connections.
After starting the pool via EdgeDB.start_link/1 or siblings,
  the client instance for the pool will be implicitly registered.
In case you want to change the behavior of your queries, you will use the EdgeDB.Client,
  which is acceptable by all EdgeDB API and will be provided to you in a callback
  in the EdgeDB.transaction/3 function.

EdgeDB.Client.State 
    



      
State for the client is an execution context that affects the execution of EdgeQL commands in different ways:
	default module.
	module aliases.
	session config.
	global values.

The most convenient way to work with the state is to use the EdgeDB API to change a required part of
  the state.
See EdgeDB.with_client_state/2, EdgeDB.with_default_module/2,
  EdgeDB.with_module_aliases/2/EdgeDB.without_module_aliases/2,
  EdgeDB.with_config/2/EdgeDB.without_config/2 and
  EdgeDB.with_globals/2/EdgeDB.without_globals/2 for more information.

EdgeDB.Sandbox 
    



      
Custom connection for tests that involve modifying the database through the driver.
This connection, when started, wraps the actual connection to EdgeDB into a transaction using
  the start transaction statement. And then further calls to EdgeDB.transaction/3 will result
  in executing declare savepoint statement instead of start transaction.
To use this module in tests, change the configuration of the :edgedb application in the config/test.exs:
config :edgedb,
  connection: EdgeDB.Sandbox
Then modify the test case to initialize the sandbox when you run the test and to clean the sandbox
  at the end of the test:
defmodule MyApp.TestCase do
  use ExUnit.CaseTemplate

  # other stuff for this case (e.g. Phoenix setup, Plug configuration, etc.)

  setup _context do
    EdgeDB.Sandbox.initialize(MyApp.EdgeDB)

    on_exit(fn ->
      EdgeDB.Sandbox.clean(MyApp.EdgeDB)
    end)

    :ok
  end
end

EdgeDB.ConfigMemory 
    



      
An immutable value represeting an EdgeDB cfg::memory value as a quantity of memory storage.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> mem = EdgeDB.query_required_single!(client, "select <cfg::memory>'5KiB'")
#EdgeDB.ConfigMemory<"5KiB">
iex(3)> EdgeDB.ConfigMemory.bytes(mem)
5120

EdgeDB.DateDuration 
    



      
An immutable value represeting an EdgeDB cal::date_duration value.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> EdgeDB.query_required_single!(client, "select <cal::date_duration>'1 year 2 days'")
#EdgeDB.DateDuration<"P1Y2D">

EdgeDB.MultiRange 
    



      
A value representing a collection of ranges.
EdgeDB.MultiRange implements Enumerable protocol for iterating over the collection.
  Each range in the collection is an instance of the EdgeDB.Range.t/0 struct.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> EdgeDB.query_required_single!(client, "select multirange([range(1, 10)])")
#EdgeDB.MultiRange<[#EdgeDB.Range<[1, 10)>]>

EdgeDB.NamedTuple 
    



      
An immutable value representing an EdgeDB named tuple value.
EdgeDB.NamedTuple implements Access behavior to access fields
  by index or key and Enumerable protocol for iterating over tuple values.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> nt = EdgeDB.query_required_single!(client, "select (a := 1, b := 'a', c := [3])")
#EdgeDB.NamedTuple<a: 1, b: "a", c: [3]>
iex(3)> nt[:b]
"a"
iex(4)> nt["c"]
[3]
iex(4)> nt[0]
1

EdgeDB.Object 
    



      
An immutable representation of an object instance returned from a query.
EdgeDB.Object implements Access behavior to access properties by key.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> object =
...(2)>  EdgeDB.query_required_single!(client, """
...(2)>   select schema::ObjectType{
...(2)>     name
...(2)>   }
...(2)>   filter .name = 'std::Object'
...(2)>   limit 1
...(2)>  """)
#EdgeDB.Object<name := "std::Object">
iex(3)> object[:name]
"std::Object"

  
    
  
  Links and links properties


In EdgeDB, objects can have links to other objects or a set of objects.
  You can use the same syntax to access links values as for object properties.
  Links can also have their own properties (denoted as @<link_prop_name> in EdgeQL syntax).
  You can use the same property name as in the query to access them from the links.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> object =
...(2)>  EdgeDB.query_required_single!(client, """
...(2)>   select schema::Property {
...(2)>       name,
...(2)>       annotations: {
...(2)>         name,
...(2)>         @value
...(2)>       }
...(2)>   }
...(2)>   filter .name = 'listen_port' and .source.name = 'cfg::Config'
...(2)>   limit 1
...(2)>  """)
#EdgeDB.Object<name := "listen_port", annotations := #EdgeDB.Set<{#EdgeDB.Object<name := "cfg::system", @value := "true">}>>
iex(3)> annotations = object[:annotations]
#EdgeDB.Set<{#EdgeDB.Object<name := "cfg::system", @value := "true">}>
iex(4)> link = Enum.at(annotations, 0)
#EdgeDB.Object<name := "cfg::system", @value := "true">
iex(5)> link["@value"]
"true"

EdgeDB.Range 
    



      
A value representing some interval of values.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> EdgeDB.query_required_single!(client, "select range(1, 10)")
#EdgeDB.Range<[1, 10)>

EdgeDB.RelativeDuration 
    



      
An immutable value represeting an EdgeDB cal::relative_duration value.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> EdgeDB.query_required_single!(client, "select <cal::relative_duration>'45.6 seconds'")
#EdgeDB.RelativeDuration<"PT45.6S">

EdgeDB.Set 
    



      
A representation of an immutable set of values returned by a query.
  Nested sets in the result are also returned as EdgeDB.Set objects.
EdgeDB.Set implements Enumerable protocol for iterating over set values.
iex(1)> {:ok, client} = EdgeDB.start_link()
iex(2)> set =
...(2)>  EdgeDB.query!(client, """
...(2)>   select schema::ObjectType{
...(2)>     name
...(2)>   }
...(2)>   filter .name IN {'std::BaseObject', 'std::Object', 'std::FreeObject'}
...(2)>   order by .name
...(2)>  """)
iex(3)> set
#EdgeDB.Set<{#EdgeDB.Object<name := "std::BaseObject">, #EdgeDB.Object<name := "std::FreeObject">, #EdgeDB.Object<name := "std::Object">}>

EdgeDB.Protocol.Codec protocol
    



      
A codec knows how to work with the internal binary data from EdgeDB.
The binary protocol specification for the codecs can be found in
  the relevant part of the EdgeDB documentation.
Useful links for codec developers:
	EdgeDB datatypes used in data descriptions.
	EdgeDB data wire formats.
	Built-in EdgeDB codec implementations.
	Custom codecs implementations.
	Guide to developing custom codecs on hex.pm
  or on edgedb.com.

A storage for each codec that the connection knows how to decode.

EdgeDB.Protocol.CustomCodec behaviour
    



      
Behaviour for custom scalar codecs.
See custom codecs development guide on hex.pm
  or on edgedb.com for more information.

EdgeDB.Protocol.Enums 
    



      
Definition for enumerations used in EdgeDB protocol.

      